ORIGIN '~beta/basiclib/betaenv';

--- lib: Attributes ---

(*Ez egy eleg gyik pelda a tobbszoros oroklodes kivaltasara. A kisnemes 
huberes es huberur is. A print fuggveny nem veletlen virtualis: azt 
tapasztaltuk, hogy ellenkezo esetben az oroklodes nem kiterjesztes, hanem
atdefinialas lesz, szemben az olvasott doksik allitasaival. Sajnos nem tudtuk
kiprobalni mas forditoval.*)

Huberes :
   (#
      name : @Text;
      
      print:<
         (# alma : @Text;
            
            do 
            ': Huberes vagyok...'->alma;
            name[] -> puttext;
            alma[] -> puttext;
            inner;
            newline;
         #);


      setName:
         (#
            temp: @Text;
            enter temp
            do temp -> name
         #)


   #);

Huberur :
   (#
      name : @Text;
      
      print:<
         (# alma : @Text;
            
            do 
            ': Huberur vagyok!' -> alma;
            name[] -> puttext;
            alma[] -> puttext;
            inner;
            newline;
         #);

      setName:
         (#
            temp: @Text;
            enter temp
            do temp -> name
         #)


   #);


Kisnemes:
   (#

      felso: @Huberur             (*Ez pelda egyedi mintara*)
      (#
         print::
         (#
            temp : @Text;

            do

            'De sajnos... nekem is van huberuram' ->temp;
            temp[] -> puttext;

         #);
      #);

      also: @Huberes
      (#
         print::
         (#
            temp : @Text;

            do

            'Viszont nekem is van huberesem!!!' ->temp;
            temp[] -> puttext;
            inner;
         #);
      #);
      


      setName:
         (#
            temp: @Text;
            enter temp
            do 
               temp -> felso.setName;
               temp -> also.setName;
         #);

      print:
         (#
            do
            
               felso.print;
               also.print;
         #);


   #);

--- program: Descriptor ---

(#

   kiraly : @Huberur;
   kisnemeske: @Kisnemes;
   paraszt : @Huberes;

   do

   'Kiraly' -> kiraly.setName;
   'Kisnemes' -> kisnemeske.setName;
   'Paraszt' -> paraszt.setName;

   kiraly.print;
   kisnemeske.print;
   paraszt.print;

#)