// demo02.ck
//
// Készítette:
// Kaluzsa Péter - ELTE - 2012/2013-2
//
// tömb típusok
//

// 10 hosszú int tömb, indexelés: 0..9
// minden indexen az alapértelmezett 0 érték van
int intArray[10];

<<<intArray>>>;
<<<intArray[0]>>>;

// tömb inicializálására is van mód
// a tömbök objektumok, ezért az @=> operátor használandó
[1,2,3,4,5] @=> int initArray[];

<<<initArray>>>;

for (0 => int i; i < initArray.size(); i++){
	chout <= initArray[i] <= " ";}
chout <= IO.newline();

// null-ra mutató int tömb
int sameArray[];
// initArray referenciáját állítjuk be sameArray-nek
initArray @=> sameArray;

// initArray ezentúl sameArray-ként is elérhető
<<<initArray>>>; <<<sameArray>>>;
chout <= sameArray[3] <= "==" <= initArray[3] <= IO.newline();

// objektum tömb - alapértelmezetten inicializált objektumokkal
Object objArray[2];
<<<objArray[0]>>>;

// objektum tömb - null referenciákkal
Object @ nullArray[3];
<<<nullArray[0]>>>;

// többdimenziós tömbök
[[[0.5, 1.2],[3.3, .1]],[[1.1, 2.],[0.3, .65]]] @=> float floatMatrix[][][];
<<<floatMatrix>>>;
<<<floatMatrix[0]>>>;
<<<floatMatrix[0][1]>>>;
<<<floatMatrix[0][1][0]>>>;

// többdimenziós tömb részdimenziója is elérhető
// a dimenziók számosságának meg kell felelniük
floatMatrix [1] @=> float subMatrix[][];

<<<subMatrix>>>;
<<<subMatrix[1][1]>>>;

// asszociatív tömbök
// üres tömb
int emptyArray[0];
// érték beállítása a "new" mezőbe
7 => emptyArray["new"];
// a statikus tömb mérete 0 marad, a 7-es érték a dinamikus tárterületre kerül
<<<emptyArray.size()>>>;
<<<emptyArray["new"]>>>;

// minden tömb használható mint asszociatív tömb
3 => intArray["0"];
<<<intArray["0"]>>>;

// az újonnan hivatkozott elemek az alapértelmezett nulla értéket tartalmazzák
<<<intArray["unused"]>>>;

// objektumoknál null referenciát!
// nem kerül inicializálásra az asszociatívan elért objektum (nullpointer hiba)
<<<objArray[0]>>>;
<<<objArray["unused"]>>>;

// kevert tömbök
// az első dimenzió üres, a második dimenzió két elemet tartalmazhat
int mixedArray[0][2];

//második dimenzió tömbjeit létrehozzuk és az asszociatív dimenzióhoz csatoljuk
new int[2] @=> mixedArray["alpha"];
[3, 4] @=> mixedArray["beta"];
[5, 6] @=> mixedArray["gamma"];

1 => mixedArray["alpha"][0];
2 => mixedArray["alpha"][1];

<<<mixedArray>>>;
<<<mixedArray["alpha"]>>>;
<<<mixedArray["alpha"][1]>>>;
<<<mixedArray["beta"]>>>;
<<<mixedArray["gamma"]>>>;
<<<mixedArray["gamma"][1]>>>;